string 命令合集

(1) 常用的 string 命令如下表所示，其中粗體部分表示 TCL 系統(tǒng)命令或參數(shù)。

(2) “str1 str2 ...”、“index1 index2 ...”等，表明參數(shù)可以指定多個(gè)。

(3) 注意各個(gè)命令使用字符串變量時(shí)，格式是 **str 還是 str。一般使用 **str 時(shí)會(huì)返回新的字符串，使用 str 時(shí)不會(huì)返回新的字符串。

字符串操作舉例

舉例：string compare/equal

TCL 中使用 string equal 進(jìn)行字符串是否相等的比較。嚴(yán)格相等返回值為 1，否則為 0 。

可選項(xiàng) -nocase 指定比較時(shí)不區(qū)分大小寫(xiě)，可選項(xiàng) -length 指定字符串長(zhǎng)度進(jìn)行比較。

set str_ref "abcd"
set str_comp1 "abce"
set str_comp2 "ABCd"
# 以下兩種方式不等
puts [string equal $str_ref $str_comp1]
puts [string equal $str_ref $str_comp2]
#以下兩種方式相等
puts [string equal -length 3 $str_ref $str_comp1]
puts [string equal -nocase $str_ref $str_comp2]
#% 0
#% 0
#% 1
#% 1

string compare 不僅能比較是否相等，還能比較 2 個(gè)字符串大小（按照 ASCII 字符排列）。當(dāng)兩個(gè)字符串間的關(guān)系為大于、等于、小于時(shí)，返回值分別為 1、0、-1。

也可以使用 -nocase、-length 選項(xiàng)。

set str_ref "abcd"
set str_comp1 "abce"
set str_comp2 "ABCd"
# abcd < abce
puts [string compare $str_ref $str_comp1]
# abcd > ABCd
puts [string compare $str_ref $str_comp2]
# 以下相等
puts [string compare -length 3 $str_ref $str_comp1]
puts [string compare -nocase $str_ref $str_comp2]


#% -1
#% 1
#% 0
#% 0

舉例：string index/range

string index 用于訪問(wèn)字符串中的單個(gè)字符，string range 用于訪問(wèn)字符串中指定范圍內(nèi)的多個(gè)字符。

set str "Forever young."
puts "3rd char: [string index $str 3]"
puts "3-6 char: [string range $str 3 6]"
#% 3rd char: e
#% 3-6 char: ever

舉例：string replace/map

string replace 可以將指定索引范圍內(nèi)的字符串替換為新的字符串。

如果沒(méi)有指定新字符串則完成刪除功能。

set str "Forever young."
# 替換 young -> happy , young -> sad
puts "[string replace $str 8 end-1 "happy"]"
puts "[string replace $str 8 end-1 "sad"]"
# 刪除 young
puts "[string replace $str 8 end-1]"
#% Forever happy.
#% Forever sad.
#% Forever .

string map 根據(jù)指定字典型變量中鍵值對(duì)的關(guān)系，將相應(yīng)的字符串進(jìn)行映射替換。原字符串中的字符相當(dāng)于字典中的鍵，新字符串替換后的值為字典中鍵對(duì)應(yīng)的值。

替換時(shí)按照字典型變量中鍵出現(xiàn)的順序進(jìn)行映射替換，剩余字符串中沒(méi)有與鍵匹配的字符，則保留原字符（串）。

set str "Forever young. Bless you."
set char_map [dict create Forever 22 \\
                          " " 33 \\
                          "young" 44 ]
puts "[string map $char_map $str]"
#%  223344.33Bless33you.

舉例：string length/repeat/reverse

string length/repeat/reverse 具有計(jì)算長(zhǎng)度、重復(fù)字符串、反轉(zhuǎn)字符串的功能。

set str "Hello, Zhihua"
puts [string repeat $str 2]
puts [string length $str]
puts [string reverse $str]
#% Hello, ZhihuaHello, Zhihua
#% 13
#% auhihZ ,olleH

舉例：string tolower/toupper

string tolower/toupper 分別返回字符串的小寫(xiě)、大寫(xiě)格式。

puts [string tolower AbcD]
puts [string toupper AbcD]


#% abcd
#% ABCD

舉例：string first/last

string first **str1 **str2 startindex

string first 用于查找第一個(gè)字符串在第二個(gè)字符串中的位置，并返回第一個(gè)匹配的索引值。命令結(jié)尾還可以指定開(kāi)始查找的索引，即查找范圍為 str2 索引之后的字符串。

string last **str1 **str2 endindex

string last 用于查找第一個(gè)字符串在第二個(gè)字符串中的位置，并返回最后一個(gè)匹配的索引值。命令結(jié)尾還可以指定結(jié)束查找的索引，即查找范圍為 str2 索引之前的字符串。

#index     2    7    12  
set str "Abab 3cab acabb"
puts [string first ab $str]
puts [string first ab $str 5]
puts [string last ab $str]
puts [string last ab $str 10]


#% 2
#% 7
#% 12
#% 7

舉例：string trim/trimleft/trimright

string trim/trimleft/trimright $str chars

根據(jù)指定的多個(gè)字符 chars，string trim/trimleft/trimright 依次刪除字符串 $str 兩端、左側(cè)、右側(cè)的字符。只要字符串兩端、左側(cè)、右側(cè)的字符存在于指定的 chars 中，則會(huì)依次被刪除，直至遇到不存在與 chars 中的字符。

如果沒(méi)有指定 chars 選項(xiàng)，則默認(rèn)刪除空格、制表符、換行符。

set str " abccICbcc "
# 默認(rèn)刪除兩邊空格
puts [string trim $str]
# 指定 chars 時(shí)不要忘記輸入空格
puts [string trim $str "abc "]
# 默認(rèn)刪除左邊空格
puts [string trimleft $str]
# 指定 chars 時(shí)沒(méi)有輸入空格，則字符串不會(huì)改變
puts [string trimleft $str "abc"]
# 默認(rèn)刪除右邊空格
puts [string trimright $str]
puts [string trimright $str "bca "]
#% abccICbcc
#% IC
#% abccICbcc 
#%  abccICbcc 
#%  abccICbcc
#%  abccIC

舉例：string wordend/wordstart

string wordend 返回字符串中包含索引字符的單詞的下一個(gè)單詞的首個(gè)字符的索引。

string wordstart 返回字符串中包含索引字符的單詞的首個(gè)字符的索引。

此命令下，任何連續(xù)的字符數(shù)字或者下劃線，或者除此之外的單個(gè)字符，例如空格，都被視為一個(gè)單詞。

下列示例中，變量有 3 個(gè)單詞：For_ever、空格、Young。

# index  0123456789
set str "For_ever Young"
puts [string wordend $str 2]
puts [string wordend $str 8]
puts [string wordend $str 10]
puts [string wordstart $str 2]
puts [string wordstart $str 8]
puts [string wordstart $str 10]


#% 8
#% 9
#% 14
#% 0
#% 8
#% 9

舉例：string is

string is class -strict -failIndex var $str

string is 命令用于判斷字符串的類(lèi)型，如果字符串符合 TCL 中指定字符類(lèi)型 ，則返回值為1 ，否則為 0。

當(dāng)指定 -strict 選項(xiàng)時(shí)，對(duì)于所有 class 字符類(lèi)型，當(dāng)字符串為空時(shí)返回值為 1。如果不指定，遇到空字符串時(shí)返回值為 1 。

當(dāng)指定了 -failIndex var 選項(xiàng)時(shí)，該命令會(huì)把第一個(gè)不符合 class 類(lèi)別字符的索引保存到變量 var 中。如果返回值為1，則不進(jìn)行賦值操作。但是當(dāng) class 為 boolean、ture 或 false 類(lèi)型時(shí)，如果返回值為 0 ，var 會(huì)被設(shè)置為0。

這里簡(jiǎn)單介紹下 Unicore 碼：統(tǒng)一碼，又稱單一碼（Unicode），它為每種語(yǔ)言中的每個(gè)字符設(shè)定了統(tǒng)一并且唯一的二進(jìn)制編碼，以滿足跨語(yǔ)言、跨平臺(tái)進(jìn)行文本轉(zhuǎn)換、處理的要求。而大多數(shù)計(jì)算機(jī)采用 ASCII 碼是表示所有大小寫(xiě)字母、數(shù)字、標(biāo)點(diǎn)符號(hào)和控制字符的 7 位編碼方案。統(tǒng)一碼包含 128 個(gè) ASCII 碼字符。

TCL 字符串系統(tǒng)類(lèi)型 class 取值如下。

現(xiàn)在對(duì)各種 class 類(lèi)型進(jìn)行舉例說(shuō)明，返回值均為 1 。

string is alpha "?éα?以及漢字"
string is alnum "1234?éα?以及漢字"
string is ascii "Forever"
string is lower "forever"
string is upper "FOREVER"
string is wordchar "Stu_No3"
string is digit 1234
string is xdigit "\\x33"
string is integer 1234
string is wideinteger 1234


string is double 1e-3
string is list {Forever Young .}
string is boolean yes
string is true 1
string is false false
string is control \\n
string is graph "￡±2"
string is print " ￡±2 "
string is punct "。\\/"
string is space "    "

下面為返回值均為 0 的幾個(gè)簡(jiǎn)單示例。

string is alpha "1234?éα?以及漢字"
string is ascii "。"
string is lower "Forever"
string is digit 123.45
string is punct " 。\\/ "
string is space "a b c"

下面是 -strict 選項(xiàng)的簡(jiǎn)單示例。

string is alpha ""
string is integer ""
string is alpha -strict ""
string is integer -strict ""


#% 1
#% 1
#% 0
#% 0

下面是 -failindex 選項(xiàng)的簡(jiǎn)單示例。

set str "MaryIs32."
string is alpha -failindex index $str
puts "Failed index: $index"
puts "Failed char: [string index $str $index]"


Failed index: 6
Failed char: 3

字符串匹配（string match）將在下一節(jié)說(shuō)明。