單片機(jī)入門教程第19課-定時、中斷實驗一

　1、利用定時器實現(xiàn)燈的閃爍
在學(xué)單片機(jī)時我們第一個例子就是燈的閃爍，那是用延時程序做的，現(xiàn)在回想起來，這樣做不很恰當(dāng)，為什么呢？我們的主程序做了燈的閃爍，就不能再干其它的事了，難道單片機(jī)只能這樣工作嗎？當(dāng)然不是，我們可以用定時器來實現(xiàn)燈的閃爍的功能。
　　例1：查詢方式
　　　ORG 0000H
　　　AJMP START
　　　ORG 30H
　　　START:
　　　MOV P1,#0FFH ;關(guān)所 燈
　　　MOV TMOD,#00000001B ;定時/計數(shù)器0工作于方式1
　　　MOV TH0,#15H
　　　MOV TL0,#0A0H ;即數(shù)5536
　　　SETB TR0 ;定時/計數(shù)器0開始運(yùn)行
　　　LOOP:JBC TF0,NEXT ;如果TF0等于1，則清TF0并轉(zhuǎn)NEXT處
　　　AJMP LOOP ;否則跳轉(zhuǎn)到LOOP處運(yùn)行
　　　NEXT:CPL P1.0
　　　MOV TH0,#15H
　　　MOV TL0,#9FH;重置定時/計數(shù)器的初值
　　　AJMP LOOP
　　　END AJMP LOOP
　　　END
　　鍵入程序，看到了什么？燈在閃爍了，這可是用定時器做的，不再是主程序的循環(huán)了。簡單地分析一下程序，為什么用JBC呢？TF0是定時/計數(shù)器0的溢出標(biāo)記位，當(dāng)定時器產(chǎn)生溢出后，該位由0變1，所以查詢該位就可知宇時時間是否已到。該位為1后，要用軟件將標(biāo)記位清0，以便下一次定時是間到時該位由0變1，所以用了JBC指令，該指位在判1轉(zhuǎn)移的同時，還將該位清0。
　　以上程序是可以實現(xiàn)燈的閃爍了，可是主程序除了讓燈閃爍外，還是不能做其他的事?。〔?，不對，我們可以在LOOP：……和AJMP LOOP指令之間插入一些指令來做其他的事情，只要保證執(zhí)行這些指令的時間少于定時時間就行了。那我們在用軟件延時程序的時候不是也可以用一些指令來替代DJNZ嗎？是的，但是那就要求你精確計算所用指令的時間，然后再減去相應(yīng)的DJNZ循環(huán)次數(shù)，很不方便，而現(xiàn)在只要求所用指令的時間少于定時時間就行，顯然要求低了。當(dāng)然，這樣的方法還是不好，所以我們常用以下的方法來實現(xiàn)。
　　程序2：用中斷實現(xiàn)
　　　ORG 0000H
　　　AJMP START
　　　ORG 000BH ;定時器0的中斷向量地址
　　　AJMP TIME0 ;跳轉(zhuǎn)到真正的定時器程序處
　　　ORG 30H
　　　START:
　　　MOV P1,#0FFH ;關(guān)所 燈
　　　MOV TMOD,#00000001B ;定時/計數(shù)器0工作于方式1
　　　MOV TH0,#15H
　　　MOV TL0,#0A0H ;即數(shù)5536
　　　SETB EA ;開總中斷允許
　　　SETB ET0 ;開定時/計數(shù)器0允許
　　　SETB TR0 ;定時/計數(shù)器0開始運(yùn)行
　　　LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
　　　TIME0: ;定時器0的中斷處理程序
　　　PUSH ACC
　　　PUSH PSW ;將PSW和ACC推入堆棧保護(hù)
　　　CPL P1.0
　　　MOV TH0,#15H
　　　MOV TL0,#0A0H ;重置定時常數(shù)
　　　POP PSW
　　　POP ACC
　　　RETI
　　　END
　　上面的例子中，定時時間一到，TF0由0變1，就會引發(fā)中斷，CPU將自動轉(zhuǎn)至000B處尋找程序并執(zhí)行，由于留給定時器中斷的空間只有8個字節(jié)，顯然不足以寫下所有有中斷處理程序，所以在000B處安排一條跳轉(zhuǎn)指令，轉(zhuǎn)到實際處理中斷的程序處，這樣，中斷程序可以寫在任意地方，也可以寫任意長度了。進(jìn)入定時中斷后，首先要保存當(dāng)前的一些狀態(tài)，程序中只演示了保存存ACC和PSW，實際工作中應(yīng)該根據(jù)需要將可能會改變的單元的值都推入堆棧進(jìn)行保護(hù)（本程序中實際不需保存護(hù)任何值，這里只作個演示）。
　　上面的兩個程序運(yùn)行后，我們發(fā)現(xiàn)燈的閃爍非?？?，根本分辨不出來，只是視覺上感到燈有些晃動而已，為什么呢？我們可以計算一下，定時器中預(yù)置的數(shù)是5536，所以每計60000個脈沖就是定時時間到，這60000個脈沖的時間是多少呢？我們的晶振是12M，所以就是60000微秒，即60毫秒，因此速度是非常快的。如果我想實現(xiàn)一個1S的定時，該怎么辦呢？在該晶振瀕率下，最長的定時也就是65。536個毫秒?。∩厦娼o出一個例子。
　　　ORG 0000H
　　　AJMP START
　　　ORG 000BH ;定時器0的中斷向量地址
　　　AJMP TIME0 ;跳轉(zhuǎn)到真正的定時器程序處
　　　ORG 30H
　　　START:
　　　MOV P1,#0FFH ;關(guān)所 燈
　　　MOV 30H,#00H ;軟件計數(shù)器預(yù)清0
　　　MOV TMOD,#00000001B ;定時/計數(shù)器0工作于方式1
　　　MOV TH0,#3CH
　　　MOV TL0,#0B0H ;即數(shù)15536
　　　SETB EA ;開總中斷允許
　　　SETB ET0 ;開定時/計數(shù)器0允許
　　　SETB TR0 ;定時/計數(shù)器0開始運(yùn)行
　　　LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
　　　TIME0: ;定時器0的中斷處理程序
　　　PUSH ACC
　　　PUSH PSW ;將PSW和ACC推入堆棧保護(hù)
　　　INC 30H
　　　MOV A,30H
　　　CJNE A,#20,T_RET ;30H單元中的值到了20了嗎?
　　　T_L1: CPL P1.0 ;到了,取反P10
　　　MOV 30H,#0 ;清軟件計數(shù)器
　　　T_RET:
　　　MOV TH0,#15H
　　　MOV TL0,#9FH ;重置定時常數(shù)
　　　POP PSW
　　　POP ACC
　　　RETI
　　　END
　　先自己分析一下，看看是怎么實現(xiàn)的？這里采用了軟件計數(shù)器的概念，思路是這樣的，先用定時/計數(shù)器0做一個50毫秒的定時器，定時是間到了以后并不是立即取反P10，而是將軟件計數(shù)器中的值加1，如果軟件計數(shù)器計到了20，就取反P10，并清掉軟件計數(shù)器中的值，否則直接返回，這樣，就變成了20次定時中斷才取反一次P10，因此定時時間就延長了成了20*50即1000毫秒了。
　　這個思路在工程中是非常有用的，有的時候我們需要若干個定時器，可51中總共才有2個，怎么辦呢？其實，只要這幾個定時的時間有一定的公約數(shù)，我們就可以用軟件定時器加以實現(xiàn)，如我要實現(xiàn)P10口所接燈按1S每次，而P11口所接燈按2S每次閃爍，怎么實現(xiàn)呢？對了我們用兩個計數(shù)器，一個在它計到20時，取反P10，并清零，就如上面所示，另一個計到40取反P11，然后清0，不就行了嗎？這部份的程序如下：
　　　ORG 0000H
　　　AJMP START
　　　ORG 000BH ;定時器0的中斷向量地址
　　　AJMP TIME0 ;跳轉(zhuǎn)到真正的定時器程序處
　　　ORG 30H
　　　START:
　　　MOV P1,#0FFH ;關(guān)所 燈
　　　MOV 30H,#00H ;軟件計數(shù)器預(yù)清0
　　　MOV TMOD,#00000001B ;定時/計數(shù)器0工作于方式1
　　　MOV TH0,#3CH
　　　MOV TL0,#0B0H ;即數(shù)15536
　　　SETB EA ;開總中斷允許
　　　SETB ET0 ;開定時/計數(shù)器0允許
　　　SETB TR0 ;定時/計數(shù)器0開始運(yùn)行
　　　LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
　　　TIME0: ;定時器0的中斷處理程序
　　　PUSH ACC
　　　PUSH PSW ;將PSW和ACC推入堆棧保護(hù)
　　　INC 30H
　　　INC 31H ;兩個計數(shù)器都加1
　　　MOV A,30H
　　　CJNE A,#20,T_NEXT ;30H單元中的值到了20了嗎?
　　　T_L1: CPL P1.0 ;到了,取反P10
　　　MOV 30H,#0 ;清軟件計數(shù)器
　　　T_NEXT:
　　　MOV A,31H
　　　CJNE A,#40,T_RET ;31h單元中的值到40了嗎?
　　　T_L2:
　　　CPL P1.1
　　　MOV 31H,#0 ;到了,取反P11,清計數(shù)器,返回
　　　T_RET:
　　　MOV TH0,#15H
　　　MOV TL0,#9FH ;重置定時常數(shù)
　　　POP PSW
　　　POP ACC
　　　RETI
　　　END
　　您能用定時器的方法實現(xiàn)前面講的流水燈嗎？試試看。